順位を使った回帰

ホーム > 製品 > nAG数値計算ライブラリ > nAG Fortranライブラリ > サンプルソースコード集 > 順位を使った回帰

Keyword: 順位, 回帰, regression, rank

概要

本サンプルは順位を使った回帰（Regression using ranks) を行うFortranによるサンプルプログラムです。本サンプルは以下に示される標本と説明変数行列を分析対象とします。このサンプルでは回帰分析を行い、スコア統計量、スコア統計量の共分散行列、パラメータ推定、パラメータ推定の共分散行列、カイ二乗統計量、パラメータ推定の標準誤差やZ統計量を算出します。

順位を使った回帰のデータ　

※本サンプルはnAG Fortranライブラリに含まれるルーチン g08raf() のExampleコードです。本サンプル及びルーチンの詳細情報は g08raf のマニュアルページをご参照ください。
ご相談やお問い合わせはこちらまで

入力データ

（本ルーチンの詳細はg08raf のマニュアルページを参照）

このデータをダウンロード

G08RAF Example Program Data
 1 2 2 0.00001
 20
 1.0 1.0 23.0
 1.0 1.0 32.0
 3.0 1.0 37.0
 4.0 1.0 41.0
 2.0 1.0 41.0
 4.0 1.0 48.0
 1.0 1.0 48.0
 5.0 1.0 55.0
 4.0 1.0 55.0
 4.0 0.0 56.0
 4.0 1.0 57.0
 4.0 1.0 57.0
 4.0 1.0 57.0
 1.0 0.0 58.0
 4.0 1.0 59.0
 5.0 0.0 59.0
 5.0 0.0 60.0
 4.0 1.0 61.0
 4.0 1.0 62.0
 3.0 1.0 62.0

１行目はタイトル行で読み飛ばされます。
２行目に標本の数（ns=1）、フィッティングされるパラメータ数（ip=2）、誤差分布のパラメータ（idist=2）、そして観測値の同順位（タイ）についての許容基準（tol=0.00001）を指定しています。
３行目に標本の観測値の数（nv=20）を指定しています。
４～２３行目に縦に標本の観測値(y)と説明変数行列(x)を指定しています。

出力結果

（本ルーチンの詳細はg08raf のマニュアルページを参照）

この出力例をダウンロード

 G08RAF Example Program Results

 Number of samples = 1
 Number of parameters fitted = 2
 Distribution = 2
 Tolerance for ties = 0.00001

 Score statistic
    -1.048   64.333

 Covariance matrix of score statistic
     0.673
    -4.159  533.670

 Parameter estimates
    -0.852    0.114

 Covariance matrix of parameter estimates
     1.560
     0.012    0.002

 Chi-squared statistic =    8.221 with 2 d.f.

 Standard errors of estimates and
 approximate z-statistics
     1.249        -0.682
     0.044         2.567

３行目には標本の数が出力されています。
４行目にはフィッティングされるパラメータ数が出力されています。
５行目には誤差分布の種類（2:ロジスティック分布）が出力されています。
６行目には観測値の同順位の許容基準が出力されています。
９行目にはスコア統計量が出力されています。
１２～１３行目にはスコア統計量の共分散行列が出力されています。
１６行目にはパラメータ推定が出力されています。
１９～２０行目にはパラメータ推定の共分散行列が出力されています。
２２行目には自由度2のカイ二乗統計量が出力されています。
２６～２７行目には推定値の標準誤差と近似Z統計量が出力されています。

ソースコード

（本ルーチンの詳細はg08raf のマニュアルページを参照）

※本サンプルソースコードは科学技術・統計計算ライブラリである「nAG Fortranライブラリ」のルーチンを呼び出します。
サンプルのコンパイル及び実行方法

このソースコードをダウンロード

    PROGRAM g08rafe

!      G08RAF Example Program Text

!      Mark 23 Release. nAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : g08raf, nag_wp
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: nin = 5, nout = 6
!      .. Local Scalars ..
       REAL (KIND=nag_wp)              :: tol
       INTEGER                         :: i, idist, ifail, ip, j, ldprvr, ldx, &
                                          lparest, lvapvec, lwork, nmax, ns,   &
                                          nsum
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE :: eta(:), parest(:), prvr(:,:),        &
                                          vapvec(:), work(:), x(:,:), y(:),    &
                                          zin(:)
       INTEGER, ALLOCATABLE            :: irank(:), iwa(:), nv(:)
!      .. Intrinsic Functions ..
       INTRINSIC                          maxval, sum
!      .. Executable Statements ..
       WRITE (nout,*) 'G08RAF Example Program Results'
       WRITE (nout,*)

!      Skip heading in data file
       READ (nin,*)

!      Read number of samples, number of parameters to be fitted,
!      error distribution parameter and tolerance criterion for ties.
       READ (nin,*) ns, ip, idist, tol

       ALLOCATE (nv(ns))

!      Read the number of observations in each sample.
       READ (nin,*) nv(1:ns)

!      Calculate NSUM, NMAX and various array lengths
       nsum = sum(nv(1:ns))
       nmax = maxval(nv(1:ns))
       ldx = nsum
       ldprvr = ip + 1
       lvapvec = nmax*(nmax+1)/2
       lparest = 4*ip + 1
       lwork = nmax*(ip+1)
       ALLOCATE (y(nsum),x(ldx,ip),prvr(ldprvr,ip),irank(nmax),zin(nmax), &
          eta(nmax),vapvec(lvapvec),parest(lparest),work(lwork),iwa(nmax))

!      Read in observations and design matrices for each sample.
       READ (nin,*) (y(i),x(i,1:ip),i=1,nsum)

!      Display input information
       WRITE (nout,99999) 'Number of samples =', ns
       WRITE (nout,99999) 'Number of parameters fitted =', ip
       WRITE (nout,99999) 'Distribution =', idist
       WRITE (nout,99998) 'Tolerance for ties =', tol

       ifail = 0
       CALL g08raf(ns,nv,nsum,y,ip,x,ldx,idist,nmax,tol,prvr,ldprvr,irank,zin, &
          eta,vapvec,parest,work,lwork,iwa,ifail)

!      Display results
       WRITE (nout,*)
       WRITE (nout,*) 'Score statistic'
       WRITE (nout,99997) parest(1:ip)
       WRITE (nout,*)
       WRITE (nout,*) 'Covariance matrix of score statistic'
       DO j = 1, ip
          WRITE (nout,99997) prvr(1:j,j)
       END DO
       WRITE (nout,*)
       WRITE (nout,*) 'Parameter estimates'
       WRITE (nout,99997) parest((ip+1):(2*ip))
       WRITE (nout,*)
       WRITE (nout,*) 'Covariance matrix of parameter estimates'
       DO i = 1, ip
          WRITE (nout,99997) prvr(i+1,1:i)
       END DO
       WRITE (nout,*)
       WRITE (nout,99996) 'Chi-squared statistic =', parest(2*ip+1), ' with', &
          ip, ' d.f.'
       WRITE (nout,*)
       WRITE (nout,*) 'Standard errors of estimates and'
       WRITE (nout,*) 'approximate z-statistics'
       WRITE (nout,99995) (parest(2*ip+1+i),parest(3*ip+1+i),i=1,ip)

99999  FORMAT (1X,A,I2)
99998  FORMAT (1X,A,F8.5)
99997  FORMAT (1X,2F9.3)
99996  FORMAT (1X,A,F9.3,A,I2,A)
99995  FORMAT (1X,F9.3,F14.3)
    END PROGRAM g08rafe

Fortranによるサンプルソースコード : 使用ルーチン名：g08raf

概要

入力データ

出力結果

ソースコード