ランダム直交行列の生成

ホーム > 製品 > nAG数値計算ライブラリ > nAG Fortranライブラリ > サンプルソースコード集 > ランダム直交行列の生成

Keyword: ランダム直交行列

概要

本サンプルはランダム直交行列の生成を行うFortranによるサンプルプログラムです。本サンプルは 4x4 のランダム直交行列を生成し出力します。

※本サンプルはnAG Fortranライブラリに含まれるルーチン g05pxf() のExampleコードです。本サンプル及びルーチンの詳細情報は g05pxf のマニュアルページをご参照ください。
ご相談やお問い合わせはこちらまで

入力データ

このデータをダウンロード

G05PXF Example Program Data
1  1  1762543      :: GENID,SUBID,SEED(1)
4  4               :: N,M
'R'  'I'           :: SIDE,INIT

１行目はタイトル行で読み飛ばされます。
２行目に使用する生成器（genid=1:nAG基本生成器）、生成器に関する情報（subid=1:GENIDが1の場合この値は参照されません）、生成器の初期値（seed=1762543）を指定しています。
３行目に行列Aの列数（n=4）と行数（m=4）を指定しています。
４行目に行列Aが右辺多重か左辺多重かどうか（side='R':右辺多重）と行列Aの恒等行列への初期化が必要かどうか（init='I':必要）を指定しています。

出力結果

（本ルーチンの詳細はg05pxf のマニュアルページを参照）

この出力例をダウンロード

 G05PXF Example Program Results

 Random Matrix
          1       2       3       4
 1   0.1756  0.7401 -0.3067 -0.5722
 2   0.6593 -0.5781 -0.2191 -0.4279
 3   0.6680  0.3172  0.6077  0.2895
 4  -0.2971 -0.1323  0.6990 -0.6369

４～８行目に生成されたランダム直交行列が出力されています。

ソースコード

（本ルーチンの詳細はg05pxf のマニュアルページを参照）

※本サンプルソースコードは科学技術・統計計算ライブラリである「nAG Fortranライブラリ」のルーチンを呼び出します。
サンプルのコンパイル及び実行方法

このソースコードをダウンロード

    PROGRAM g05pxfe

!      G05PXF Example Program Text

!      Mark 23 Release. nAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : g05kff, g05pxf, nag_wp, x04caf
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: lseed = 1, nin = 5, nout = 6
!      .. Local Scalars ..
       INTEGER                         :: genid, i, ifail, lda, lstate, m, n,  &
                                          subid
       CHARACTER (1)                   :: init, side
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE :: a(:,:)
       INTEGER                         :: seed(lseed)
       INTEGER, ALLOCATABLE            :: state(:)
!      .. Executable Statements ..
       WRITE (nout,*) 'G05PXF Example Program Results'
       WRITE (nout,*)
       FLUSH (nout)

!      Skip heading in data file
       READ (nin,*)

!      Read in the base generator information and seed
       READ (nin,*) genid, subid, seed(1)

!      Initial call to initialiser to get size of STATE array
       lstate = 0
       ALLOCATE (state(lstate))
       ifail = 0
       CALL g05kff(genid,subid,seed,lseed,state,lstate,ifail)

!      Reallocate STATE
       DEALLOCATE (state)
       ALLOCATE (state(lstate))

!      Initialize the generator to a repeatable sequence
       ifail = 0
       CALL g05kff(genid,subid,seed,lseed,state,lstate,ifail)

!      Read in the problem size
       READ (nin,*) n, m

!      Read in control parameters
       READ (nin,*) side, init

       lda = m
       ALLOCATE (a(lda,n))

!      Read in A if required
       IF (init=='N' .OR. init=='n') THEN
          READ (nin,*) (a(i,1:n),i=1,m)
       END IF

!      Generate the random orthogonal matrix
       ifail = 0
       CALL g05pxf(side,init,m,n,state,a,lda,ifail)

!      Display the results
       ifail = 0
       CALL x04caf('General',' ',m,n,a,lda,'Random Matrix',ifail)

    END PROGRAM g05pxfe

Fortranによるサンプルソースコード : 使用ルーチン名：g05pxf

概要

入力データ

出力結果

ソースコード