負の二項分布から整数疑似乱数ベクトルを生成

ホーム > 製品 > nAG数値計算ライブラリ > nAG Fortranライブラリ > サンプルソースコード集 > 負の二項分布から整数疑似乱数ベクトルを生成

Keyword: 負の二項分布, 整数疑似乱数ベクトル

概要

本サンプルは負の二項分布から整数疑似乱数ベクトルの生成を行うFortranによるサンプルプログラムです。本サンプルは確率が以下で表される、m=60、p=0.999の負の二項分布から20個の整数疑似乱数をを生成し出力します。

負の二項分布のデータ　

※本サンプルはnAG Fortranライブラリに含まれるルーチン g05thf() のExampleコードです。本サンプル及びルーチンの詳細情報は g05thf のマニュアルページをご参照ください。
ご相談やお問い合わせはこちらまで

入力データ

このデータをダウンロード

G05THF Example Program Data
1  1  1762543     :: GENID,SUBID,SEED(1)
20                :: N
0.999  60         :: P,M

１行目はタイトル行で読み飛ばされます。
２行目に使用する生成器（genid=1:nAG基本生成器）、生成器に関する情報（subid=1:GENIDが1の場合この値は参照されません）、生成器の初期値（seed=1762543）を指定しています。
３行目に生成される疑似乱数の数（n=20）を指定しています。
４行目に成功確率（p=0.999）、失敗数（m=60）を指定しています。

出力結果

（本ルーチンの詳細はg05thf のマニュアルページを参照）

この出力例をダウンロード

 G05THF Example Program Results

        62339
        50505
        64863
        66289
        50434
        59461
        57365
        65965
        59572
        63104
        47833
        54735
        62075
        48018
        61458
        55190
        54263
        80995
        70129
        60200

３～２２行目に生成された整数疑似乱数が出力されています。

ソースコード

（本ルーチンの詳細はg05thf のマニュアルページを参照）

※本サンプルソースコードは科学技術・統計計算ライブラリである「nAG Fortranライブラリ」のルーチンを呼び出します。
サンプルのコンパイル及び実行方法

このソースコードをダウンロード

    PROGRAM g05thfe

!      G05THF Example Program Text

!      Mark 23 Release. nAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : g05kff, g05thf, nag_wp, x02amf
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: lseed = 1, maxlr = 5000, nin = 5,    &
                                          nout = 6
!      .. Local Scalars ..
       REAL (KIND=nag_wp)              :: p
       INTEGER                         :: genid, ifail, lr, lstate, m, mode,   &
                                          n, subid
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE :: r(:)
       INTEGER                         :: seed(lseed)
       INTEGER, ALLOCATABLE            :: state(:), x(:)
!      .. Intrinsic Functions ..
       INTRINSIC                          int, real, sqrt
!      .. Executable Statements ..
       WRITE (nout,*) 'G05THF Example Program Results'
       WRITE (nout,*)

!      Skip heading in data file
       READ (nin,*)

!      Read in the base generator information and seed
       READ (nin,*) genid, subid, seed(1)

!      Initial call to initialiser to get size of STATE array
       lstate = 0
       ALLOCATE (state(lstate))
       ifail = 0
       CALL g05kff(genid,subid,seed,lseed,state,lstate,ifail)

!      Reallocate STATE
       DEALLOCATE (state)
       ALLOCATE (state(lstate))

!      Initialize the generator to a repeatable sequence
       ifail = 0
       CALL g05kff(genid,subid,seed,lseed,state,lstate,ifail)

!      Read in sample size
       READ (nin,*) n

!      Read in the distribution parameters
       READ (nin,*) p, m

!      Use suggested value for LR
       IF (1.0E0_nag_wp-p<x02amf()) THEN
!         P is too close to 1.0 to calculate LR, so
!         set to MAXLR, which means we will use MODE = 3
          lr = maxlr
       ELSE
          lr = int(2.8E1_nag_wp+(2.0E1_nag_wp*sqrt(real(m,kind=nag_wp)* &
             p)+3.0E1_nag_wp*p)/(1.0E0_nag_wp-p))
       END IF

!      If R is a reasonable size use MODE = 2
!      else do not reference R and use MODE = 3
       IF (lr<maxlr) THEN
          mode = 2
       ELSE
          mode = 3
          lr = 0
       END IF

       ALLOCATE (x(n),r(lr))

!      Generate the variates
       ifail = 0
       CALL g05thf(mode,n,m,p,r,lr,state,x,ifail)

!      Display the variates
       WRITE (nout,99999) x(1:n)

99999  FORMAT (1X,I12)
    END PROGRAM g05thfe

負の二項分布から整数疑似乱数ベクトルを生成

Fortranによるサンプルソースコード : 使用ルーチン名：g05thf

概要

入力データ

出力結果

ソースコード