超幾何分布から整数疑似乱数ベクトルを生成

ホーム > 製品 > nAG数値計算ライブラリ > nAG Fortranライブラリ > サンプルソースコード集 > 超幾何分布から整数疑似乱数ベクトルを生成

Keyword: 超幾何分布, 整数疑似乱数ベクトル

概要

本サンプルは超幾何分布から整数疑似乱数ベクトルの生成を行うFortranによるサンプルプログラムです。本サンプルは確率が以下で表される、l=500、m=900、n=1000の超幾何分布から20個の整数疑似乱数を生成し出力します。

超幾何分布のデータ　

※本サンプルはnAG Fortranライブラリに含まれるルーチン g05tef() のExampleコードです。本サンプル及びルーチンの詳細情報は g05tef のマニュアルページをご参照ください。
ご相談やお問い合わせはこちらまで

入力データ

このデータをダウンロード

G05TEF Example Program Data
1  1  1762543     :: GENID,SUBID,SEED(1)
20                :: N
500  900  1000    :: NS,M,NP
10 5 100
100 2500 10000
9780 50 10000

１行目はタイトル行で読み飛ばされます。
２行目に使用する生成器（genid=1:nAG基本生成器）、生成器に関する情報（subid=1:GENIDが1の場合この値は参照されません）、生成器の初期値（seed=1762543）を指定しています。
３行目に生成される疑似乱数の数（n=20）を指定しています。
４行目に超幾何分布の標本サイズ（ns=500）、特定の項目の数（m=900）、母集団の大きさ（np=1000）を指定しています。

出力結果

（本ルーチンの詳細はg05tef のマニュアルページを参照）

この出力例をダウンロード

 G05TEF Example Program Results

          452
          444
          453
          454
          444
          450
          449
          454
          450
          452
          442
          447
          451
          442
          451
          447
          447
          462
          456
          450

３～２２行目に生成された整数疑似乱数が出力されています。

ソースコード

（本ルーチンの詳細はg05tef のマニュアルページを参照）

※本サンプルソースコードは科学技術・統計計算ライブラリである「nAG Fortranライブラリ」のルーチンを呼び出します。
サンプルのコンパイル及び実行方法

このソースコードをダウンロード

    PROGRAM g05tefe

!      G05TEF Example Program Text

!      Mark 23 Release. nAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : g05kff, g05tef, nag_wp
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: lseed = 1, maxlr = 5000, nin = 5,    &
                                          nout = 6
!      .. Local Scalars ..
       REAL (KIND=nag_wp)              :: anp, tmp
       INTEGER                         :: genid, ifail, lr, lstate, m, mode,   &
                                          n, np, ns, subid
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE :: r(:)
       INTEGER                         :: seed(lseed)
       INTEGER, ALLOCATABLE            :: state(:), x(:)
!      .. Intrinsic Functions ..
       INTRINSIC                          int, real, sqrt
!      .. Executable Statements ..
       WRITE (nout,*) 'G05TEF Example Program Results'
       WRITE (nout,*)

!      Skip heading in data file
       READ (nin,*)

!      Read in the base generator information and seed
       READ (nin,*) genid, subid, seed(1)

!      Initial call to initialiser to get size of STATE array
       lstate = 0
       ALLOCATE (state(lstate))
       ifail = 0
       CALL g05kff(genid,subid,seed,lseed,state,lstate,ifail)

!      Reallocate STATE
       DEALLOCATE (state)
       ALLOCATE (state(lstate))

!      Initialize the generator to a repeatable sequence
       ifail = 0
       CALL g05kff(genid,subid,seed,lseed,state,lstate,ifail)

!      Read in sample size
       READ (nin,*) n

!      Read in the distribution parameters
       READ (nin,*) ns, m, np

!      Use suggested value for LR
       anp = real(np,kind=nag_wp)
       tmp = (real(np-m,kind=nag_wp)/anp)*(real(np-ns,kind=nag_wp)/anp)* &
          (real(m*ns,kind=nag_wp)/real(np,kind=nag_wp))
       lr = 28 + 20*int(sqrt(tmp))

!      If R is a reasonable size use MODE = 2
!      else do not reference R and use MODE = 3
       IF (lr<maxlr) THEN
          mode = 2
       ELSE
          mode = 3
          lr = 0
       END IF

       ALLOCATE (x(n),r(lr))

!      Generate the variates
       ifail = -1
       CALL g05tef(mode,n,ns,np,m,r,lr,state,x,ifail)

!      Display the variates
       WRITE (nout,99999) x(1:n)

99999  FORMAT (1X,I12)
    END PROGRAM g05tefe

Fortranによるサンプルソースコード : 使用ルーチン名：g05tef

概要

入力データ

出力結果

ソースコード