Keyword: 幾何分布, 整数疑似乱数ベクトル
概要
本サンプルは幾何分布から整数疑似乱数ベクトルの生成を行うFortranによるサンプルプログラムです。 本サンプルは確率が以下で表される、p=0.001の幾何分布から10個の整数疑似乱数を生成し出力します。
※本サンプルはnAG Fortranライブラリに含まれるルーチン g05tcf() のExampleコードです。本サンプル及びルーチンの詳細情報は g05tcf のマニュアルページをご参照ください。
ご相談やお問い合わせはこちらまで
入力データ
（本ルーチンの詳細はg05tcf のマニュアルページを参照）1 2 3 4
| このデータをダウンロード |
G05TCF Example Program Data 1 1 1762543 :: GENID,SUBID,SEED(1) 10 :: N 0.001 :: P
- １行目はタイトル行で読み飛ばされます。
- ２行目に使用する生成器（genid=1:nAG基本生成器）、生成器に関する情報（subid=1:GENIDが1の場合この値は参照されません）、生成器の初期値（seed=1762543）を指定しています。
- ３行目に生成される疑似乱数の数（n=10）を指定しています。
- ４行目に幾何分布の成功確率p（=0.001）を指定しています。
出力結果
（本ルーチンの詳細はg05tcf のマニュアルページを参照）1 2 3 4 5 6 7 8 9 10 11 12
| この出力例をダウンロード |
G05TCF Example Program Results
451
2238
292
225
2256
708
955
239
696
397
- ３～１２行目に生成された整数疑似乱数が出力されています。
ソースコード
（本ルーチンの詳細はg05tcf のマニュアルページを参照）
※本サンプルソースコードは科学技術・統計計算ライブラリである「nAG Fortranライブラリ」のルーチンを呼び出します。
サンプルのコンパイル及び実行方法
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82
| このソースコードをダウンロード |
PROGRAM g05tcfe
! G05TCF Example Program Text
! Mark 23 Release. nAG Copyright 2011.
! .. Use Statements ..
USE nag_library, ONLY : g05kff, g05tcf, nag_wp, x02amf
! .. Implicit None Statement ..
IMPLICIT NONE
! .. Parameters ..
INTEGER, PARAMETER :: lseed = 1, maxlr = 5000, nin = 5, &
nout = 6
! .. Local Scalars ..
REAL (KIND=nag_wp) :: p
INTEGER :: genid, ifail, lr, lstate, mode, n, &
subid
! .. Local Arrays ..
REAL (KIND=nag_wp), ALLOCATABLE :: r(:)
INTEGER :: seed(lseed)
INTEGER, ALLOCATABLE :: state(:), x(:)
! .. Intrinsic Functions ..
INTRINSIC int
! .. Executable Statements ..
WRITE (nout,*) 'G05TCF Example Program Results'
WRITE (nout,*)
! Skip heading in data file
READ (nin,*)
! Read in the base generator information and seed
READ (nin,*) genid, subid, seed(1)
! Initial call to initialiser to get size of STATE array
lstate = 0
ALLOCATE (state(lstate))
ifail = 0
CALL g05kff(genid,subid,seed,lseed,state,lstate,ifail)
! Reallocate STATE
DEALLOCATE (state)
ALLOCATE (state(lstate))
! Initialize the generator to a repeatable sequence
ifail = 0
CALL g05kff(genid,subid,seed,lseed,state,lstate,ifail)
! Read in sample size
READ (nin,*) n
! Read in the distribution parameters
READ (nin,*) p
! Use suggested value for LR
IF (p<x02amf()) THEN
! P is too close to 0.0 to calculate LR, so
! set to MAXLR, which means we will use MODE = 3
lr = maxlr
ELSE
lr = int(8.0E0_nag_wp+4.2E1_nag_wp/p)
END IF
! If R is a reasonable size use MODE = 2
! else do not reference R and use MODE = 3
IF (lr<maxlr) THEN
mode = 2
ELSE
mode = 3
lr = 0
END IF
ALLOCATE (x(n),r(lr))
! Generate the variates
ifail = 0
CALL g05tcf(mode,n,p,r,lr,state,x,ifail)
! Display the variates
WRITE (nout,99999) x(1:n)
99999 FORMAT (1X,I12)
END PROGRAM g05tcfe