ガンマ誤差をもつ一般化線形モデルのフィット

ホーム > 製品 > nAG数値計算ライブラリ > nAG Fortranライブラリ > サンプルソースコード集 > ガンマ誤差をもつ一般化線形モデルのフィット

Keyword: ガンマ誤差, 一般化線形モデル, フィット

概要

本サンプルはガンマ誤差をもつ一般化線形モデルのフィットを行うFortranによるサンプルプログラムです。本サンプルは以下に示されるデータについて一般化線形モデルのフィットを行います。

一般化線形モデルのフィットのデータ　

※本サンプルはnAG Fortranライブラリに含まれるルーチン g02gdf() のExampleコードです。本サンプル及びルーチンの詳細情報は g02gdf のマニュアルページをご参照ください。
ご相談やお問い合わせはこちらまで

入力データ

このデータをダウンロード

G02GDF Example Program Data
'R' 'M' 'N' 'U' 10 1 0.0 :: LINK,MEAN,OFFSET,WEIGHT,N,M,S
1.0  1.0
1.0  0.3
1.0 10.5
1.0  9.7
1.0 10.9
0.0 0.62
0.0 0.12
0.0 0.09
0.0 0.50
0.0 2.14                 :: End of X,Y
 1                       :: ISX
0  1.0E-6  5.0E-5  0     :: IPRINT,EPS,TOL,MAXIT

１行目はタイトル行で読み飛ばされます。
２行目はどのリンク関数が使用されるか（link='R':相互リンク（reciprocal link））、一般化線形モデルの引数に切片が含まれるかどうか（mean='M':切片を含める）、オフセットが必要かどうか（offset='N':不要）、重みづけをするかどうか（weight='U':重みづけをしない）、観測値の数（n=10）、独立変数の数（m=1）、モデルのスケール引数（s=0.0:スケール引数が残差平均平方から推定される）を指定しています。
３～１２行目に独立変数の観測値(x)と従属変数の観測値(y)を指定しています。
１３行目はモデルに独立変数が含まれるかどうか(isx)を指定しています。"1"は含まれることを意味します。
１４行目は反復の情報の出力が必要かどうか（iprint=0:不要）、独立変数がフルランクかどうかそうでない場合ランクは何か（eps=1.0E-6）、モデルのフィットに必要な正確さ（tol=5.0E-5）、最大反復数（maxit=0:デフォルト値10が使用される）を指定しています。

出力結果

（本ルーチンの詳細はg02gdf のマニュアルページを参照）

この出力例をダウンロード

 G02GDF Example Program Results

 Deviance =   0.3503E+02
 Degrees of freedom = 8

      Estimate     Standard error

         1.4408        0.6678
        -1.2865        0.6717

      Y        FV     Residual        H

     1.0      6.48     -1.3909     0.200
     0.3      6.48     -1.9228     0.200
    10.5      6.48      0.5236     0.200
     9.7      6.48      0.4318     0.200
    10.9      6.48      0.5678     0.200
     0.6      0.69     -0.1107     0.200
     0.1      0.69     -1.3287     0.200
     0.1      0.69     -1.4815     0.200
     0.5      0.69     -0.3106     0.200
     2.1      0.69      1.3665     0.200

３行目にデビアンス（deviance）が出力されています。
４行目に自由度が出力されています。
６～９行目に一般化線形モデルの引数の推定値と標準誤差が出力されています。
１１～２２行目に従属変数の観測値、フィットされた値、残差、てこ値が出力されています。

ソースコード

（本ルーチンの詳細はg02gdf のマニュアルページを参照）

※本サンプルソースコードは科学技術・統計計算ライブラリである「nAG Fortranライブラリ」のルーチンを呼び出します。
サンプルのコンパイル及び実行方法

このソースコードをダウンロード

    PROGRAM g02gdfe

!      G02GDF Example Program Text

!      Mark 23 Release. nAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : g02gdf, nag_wp
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: nin = 5, nout = 6
!      .. Local Scalars ..
       REAL (KIND=nag_wp)              :: a, dev, eps, s, tol
       INTEGER                         :: i, idf, ifail, ip, iprint, irank,    &
                                          ldv, ldx, lwk, lwt, m, maxit, n
       CHARACTER (1)                   :: link, mean, offset, weight
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE :: b(:), cov(:), se(:), v(:,:), wk(:),  &
                                          wt(:), x(:,:), y(:)
       INTEGER, ALLOCATABLE            :: isx(:)
!      .. Intrinsic Functions ..
       INTRINSIC                          count
!      .. Executable Statements ..
       WRITE (nout,*) 'G02GDF Example Program Results'
       WRITE (nout,*)

!      Skip heading in data file
       READ (nin,*)

!      Read in the problem size
       READ (nin,*) link, mean, offset, weight, n, m, s

       IF (weight=='W' .OR. weight=='w') THEN
          lwt = n
       ELSE
          lwt = 0
       END IF
       ldx = n
       ALLOCATE (x(ldx,m),y(n),wt(lwt),isx(m))

!      Read in data
       IF (lwt>0) THEN
          READ (nin,*) (x(i,1:m),y(i),wt(i),i=1,n)
       ELSE
          READ (nin,*) (x(i,1:m),y(i),i=1,n)
       END IF

!      Read in variable inclusion flags
       READ (nin,*) isx(1:m)

!      Calculate IP
       ip = count(isx(1:m)>0)
       IF (mean=='M' .OR. mean=='m') THEN
          ip = ip + 1
       END IF

!      Read in power for exponential link
       IF (link=='E' .OR. link=='e') THEN
          READ (nin,*) a
       END IF

       ldv = n
       lwk = (ip*ip+3*ip+22)/2
       ALLOCATE (b(ip),se(ip),cov(ip*(ip+1)/2),v(ldv,ip+7),wk(lwk))

!      Read in the offset
       IF (offset=='Y' .OR. offset=='y') THEN
          READ (nin,*) v(1:n,7)
       END IF

!      Read in control parameters
       READ (nin,*) iprint, eps, tol, maxit

!      Fit generalized linear model with Gamma errors
       ifail = -1
       CALL g02gdf(link,mean,offset,weight,n,x,ldx,m,isx,ip,y,wt,s,a,dev,idf, &
          b,irank,se,cov,v,ldv,tol,maxit,iprint,eps,wk,ifail)
       IF (ifail/=0) THEN
          IF (ifail<7) THEN
             GO TO 20
          END IF
       END IF

!      Display results
       WRITE (nout,99999) 'Deviance = ', dev
       WRITE (nout,99998) 'Degrees of freedom = ', idf
       WRITE (nout,*)
       WRITE (nout,*) '     Estimate     Standard error'
       WRITE (nout,*)
       WRITE (nout,99997) (b(i),se(i),i=1,ip)
       WRITE (nout,*)
       WRITE (nout,*) '     Y        FV     Residual        H'
       WRITE (nout,*)
       WRITE (nout,99996) (y(i),v(i,2),v(i,5),v(i,6),i=1,n)

20     CONTINUE

99999  FORMAT (1X,A,E12.4)
99998  FORMAT (1X,A,I0)
99997  FORMAT (1X,2F14.4)
99996  FORMAT (1X,F7.1,F10.2,F12.4,F10.3)
    END PROGRAM g02gdfe

ガンマ誤差をもつ一般化線形モデルのフィット

Fortranによるサンプルソースコード : 使用ルーチン名：g02gdf

概要

入力データ

出力結果

ソースコード