Keyword: ２項誤差, 一般化線形モデル, フィット
概要
本サンプルは２項誤差をもつ一般化線形モデルのフィットを行うFortranによるサンプルプログラムです。 本サンプルは以下に示されるデータについて一般化線形モデルのフィットを行います。
※本サンプルはnAG Fortranライブラリに含まれるルーチン g02gbf() のExampleコードです。本サンプル及びルーチンの詳細情報は g02gbf のマニュアルページをご参照ください。
ご相談やお問い合わせはこちらまで
入力データ
（本ルーチンの詳細はg02gbf のマニュアルページを参照）1 2 3 4 5 6 7
| このデータをダウンロード |
G02GBF Example Program Data 'G' 'M' 'N' 'U' 3 1 :: LINK,OFFSET,WEIGHT,N,M 1.0 19. 516. 0.0 29. 560. -1.0 24. 293. :: End of X,Y,T 1 :: ISX 0 1.0E-6 5.0E-5 10 :: IPRINT,EPS,TOL,MAXIT
- １行目はタイトル行で読み飛ばされます。
- ２行目はどのリンク関数が使用されるか（link='G':ロジスティックリンク）、一般化線形モデルの引数に切片が含まれるかどうか（mean='M':切片を含める）、オフセットが必要かどうか（offset='N':不要）、重みづけをするかどうか（weight='U':重みづけをしない）、観測値の数（n=3）、独立変数の数（m=1）を指定しています。
- ３～５行目に独立変数の観測値(x)、従属変数の観測値(y)と２項分母(t)を指定しています。
- ６行目はモデルに独立変数が含まれるかどうか(isx)を指定しています。"1"は含まれることを意味します。
- ７行目は反復の情報の出力が必要かどうか（iprint=0:不要）、独立変数がフルランクかどうかそうでない場合ランクは何か（eps=1.0E-6）、モデルのフィットに必要な正確さ（tol=5.0E-5）、最大反復数（maxit=10）を指定しています。
出力結果
（本ルーチンの詳細はg02gbf のマニュアルページを参照）1 2 3 4 5 6 7 8 9 10 11 12 13 14 15
| この出力例をダウンロード |
G02GBF Example Program Results
Deviance = 0.7354E-01
Degrees of freedom = 1
Estimate Standard error
-2.8682 0.1217
-0.4264 0.1598
N Y FV Residual H
516.0 19.0 18.45 0.1296 0.769
560.0 29.0 30.10 -0.2070 0.422
293.0 24.0 23.45 0.1178 0.809
- ３行目にデビアンス（deviance）が出力されています。
- ４行目に自由度が出力されています。
- ６～９行目に一般化線形モデルの引数の推定値と標準誤差が出力されています。
- １１～１５行目に２項分母、従属変数の観測値、フィットされた値、残差、てこ値が出力されています。
ソースコード
（本ルーチンの詳細はg02gbf のマニュアルページを参照）
※本サンプルソースコードは科学技術・統計計算ライブラリである「nAG Fortranライブラリ」のルーチンを呼び出します。
サンプルのコンパイル及び実行方法
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98
| このソースコードをダウンロード |
PROGRAM g02gbfe
! G02GBF Example Program Text
! Mark 23 Release. nAG Copyright 2011.
! .. Use Statements ..
USE nag_library, ONLY : g02gbf, nag_wp
! .. Implicit None Statement ..
IMPLICIT NONE
! .. Parameters ..
INTEGER, PARAMETER :: nin = 5, nout = 6
! .. Local Scalars ..
REAL (KIND=nag_wp) :: dev, eps, tol
INTEGER :: i, idf, ifail, ip, iprint, irank, &
ldv, ldx, lwk, lwt, m, maxit, n
CHARACTER (1) :: link, mean, offset, weight
! .. Local Arrays ..
REAL (KIND=nag_wp), ALLOCATABLE :: b(:), cov(:), se(:), t(:), v(:,:), &
wk(:), wt(:), x(:,:), y(:)
INTEGER, ALLOCATABLE :: isx(:)
! .. Intrinsic Functions ..
INTRINSIC count
! .. Executable Statements ..
WRITE (nout,*) 'G02GBF Example Program Results'
WRITE (nout,*)
! Skip heading in data file
READ (nin,*)
! Read in the problem size
READ (nin,*) link, mean, offset, weight, n, m
IF (weight=='W' .OR. weight=='w') THEN
lwt = n
ELSE
lwt = 0
END IF
ldx = n
ALLOCATE (x(ldx,m),y(n),t(n),wt(lwt),isx(m))
! Read in data
IF (lwt>0) THEN
READ (nin,*) (x(i,1:m),y(i),t(i),wt(i),i=1,n)
ELSE
READ (nin,*) (x(i,1:m),y(i),t(i),i=1,n)
END IF
! Read in variable inclusion flags
READ (nin,*) isx(1:m)
! Calculate IP
ip = count(isx(1:m)>0)
IF (mean=='M' .OR. mean=='m') THEN
ip = ip + 1
END IF
ldv = n
lwk = (ip*ip+3*ip+22)/2
ALLOCATE (b(ip),se(ip),cov(ip*(ip+1)/2),v(ldv,ip+7),wk(lwk))
! Read in the offset
IF (offset=='Y' .OR. offset=='y') THEN
READ (nin,*) v(1:n,7)
END IF
! Read in the control parameters
READ (nin,*) iprint, eps, tol, maxit
! Fit generalized linear model with Binomial errors
ifail = -1
CALL g02gbf(link,mean,offset,weight,n,x,ldx,m,isx,ip,y,t,wt,dev,idf,b, &
irank,se,cov,v,ldv,tol,maxit,iprint,eps,wk,ifail)
IF (ifail/=0) THEN
IF (ifail<7) THEN
GO TO 20
END IF
END IF
! Display results
WRITE (nout,99999) 'Deviance = ', dev
WRITE (nout,99998) 'Degrees of freedom = ', idf
WRITE (nout,*)
WRITE (nout,*) ' Estimate Standard error'
WRITE (nout,*)
WRITE (nout,99997) (b(i),se(i),i=1,ip)
WRITE (nout,*)
WRITE (nout,*) ' N Y FV Residual H'
WRITE (nout,*)
WRITE (nout,99996) (t(i),y(i),v(i,2),v(i,5),v(i,6),i=1,n)
20 CONTINUE
99999 FORMAT (1X,A,E12.4)
99998 FORMAT (1X,A,I0)
99997 FORMAT (1X,2F14.4)
99996 FORMAT (1X,2F10.1,F10.2,F12.4,F10.3)
END PROGRAM g02gbfe