実対称行列の全ての固有値とオプションで全ての固有ベクトルを計算

ホーム > 製品 > nAG数値計算ライブラリ > nAG Fortranライブラリ > サンプルソースコード集 > 実対称行列の全ての固有値とオプションで全ての固有ベクトルを計算

Keyword: 実対称行列, 固有値, 固有ベクトル

概要

本サンプルは実対称行列の全ての固有値とオプションで全ての固有ベクトルの計算を行うFortranによるサンプルプログラムです。本サンプルは以下に示される実対称行列の全ての固有値と全ての固有ベクトルを計算し出力します。

実対称行列のデータ　

※本サンプルはnAG Fortranライブラリに含まれるルーチン f08fcf() のExampleコードです。本サンプル及びルーチンの詳細情報は f08fcf のマニュアルページをご参照ください。
ご相談やお問い合わせはこちらまで

入力データ

このデータをダウンロード

F08FCF Example Program Data
  4                         :Value of N
  'L'                       :Value of UPLO
  1.0   
  2.0   2.0   
  3.0   3.0   3.0
  4.0   4.0   4.0   4.0     :End of matrix A
  'V'                       :Value of JOB

１行目はタイトル行で読み飛ばされます。
２行目に行列Aの次数(n)を指定しています。
３行目に行列Aの上三角部分を格納するか下三角部分を格納するか(uplo)を指定しています。"L"は下三角部分を格納することを意味します。
４～７行目に行列Aの要素を指定しています。
８行目に固有ベクトルを計算するかどうか(job)を指定しています。"V"は固有値と固有ベクトルが計算されることを意味します。

出力結果

（本ルーチンの詳細はf08fcf のマニュアルページを参照）

この出力例をダウンロード

 F08FCF Example Program Results

 Eigenvalues
    -2.0531 -0.5146 -0.2943 12.8621

 Eigenvectors
          1       2       3       4
 1  -0.7003 -0.5144 -0.2767 -0.4103
 2  -0.3592  0.4851  0.6634 -0.4422
 3   0.1569  0.5420 -0.6504 -0.5085
 4   0.5965 -0.4543  0.2457 -0.6144

４行目に固有値が出力されています。
７～１１行目に固有ベクトルが出力されています。

ソースコード

（本ルーチンの詳細はf08fcf のマニュアルページを参照）

※本サンプルソースコードは科学技術・統計計算ライブラリである「nAG Fortranライブラリ」のルーチンを呼び出します。
サンプルのコンパイル及び実行方法

このソースコードをダウンロード

    PROGRAM f08fcfe

!      F08FCF Example Program Text

!      Mark 23 Release. nAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : dsyevd, nag_wp, x04caf
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: nin = 5, nout = 6
!      .. Local Scalars ..
       INTEGER                         :: i, ifail, info, lda, liwork, lwork, n
       CHARACTER (1)                   :: job, uplo
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE :: a(:,:), w(:), work(:)
       INTEGER, ALLOCATABLE            :: iwork(:)
!      .. Executable Statements ..
       WRITE (nout,*) 'F08FCF Example Program Results'
!      Skip heading in data file
       READ (nin,*)
       READ (nin,*) n
       lda = n
       liwork = 5*n + 3
       lwork = 2*n*n + 6*n + 1
       ALLOCATE (a(lda,n),w(n),work(lwork),iwork(liwork))

!      Read A from data file

       READ (nin,*) uplo
       IF (uplo=='U') THEN
          READ (nin,*) (a(i,i:n),i=1,n)
       ELSE IF (uplo=='L') THEN
          READ (nin,*) (a(i,1:i),i=1,n)
       END IF

       READ (nin,*) job

!      Calculate all the eigenvalues and eigenvectors of A
!      The nAG name equivalent of dsyevd is f08fcf
       CALL dsyevd(job,uplo,n,a,lda,w,work,lwork,iwork,liwork,info)

       WRITE (nout,*)
       IF (info>0) THEN
          WRITE (nout,*) 'Failure to converge.'
       ELSE

!         Print eigenvalues and eigenvectors

          WRITE (nout,*) 'Eigenvalues'
          WRITE (nout,99999) w(1:n)
          WRITE (nout,*)
          FLUSH (nout)

!         ifail: behaviour on error exit
!                =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
          ifail = 0
          CALL x04caf('General',' ',n,n,a,lda,'Eigenvectors',ifail)

       END IF

99999  FORMAT (3X,(8F8.4))
    END PROGRAM f08fcfe

実対称行列の全ての固有値とオプションで全ての固有ベクトルを計算

Fortranによるサンプルソースコード : 使用ルーチン名：f08fcf

概要

入力データ

出力結果

ソースコード