実一般矩形行列のLQ分解

ホーム > 製品 > nAG数値計算ライブラリ > nAG Fortranライブラリ > サンプルソースコード集 > 実一般矩形行列のLQ分解

Keyword: 実一般矩形行列, LQ分解

概要

本サンプルは実一般矩形行列のLQ分解を行うFortranによるサンプルプログラムです。本サンプルは以下に示される不定線形方程式をLQ分解を用いて解き、最小ノルム解を出力します。

実一般矩形行のデータ　

※本サンプルはnAG Fortranライブラリに含まれるルーチン f08ahf() のExampleコードです。本サンプル及びルーチンの詳細情報は f08ahf のマニュアルページをご参照ください。
ご相談やお問い合わせはこちらまで

入力データ

このデータをダウンロード

F08AHF Example Program Data
  4  6  2                                   :Values of M, N and NRHS
 -5.42   3.28  -3.68   0.27   2.06   0.46
 -1.65  -3.40  -3.20  -1.03  -4.06  -0.01
 -0.37   2.35   1.90   4.31  -1.76   1.13
 -3.15  -0.11   1.99  -2.70   0.26   4.50   :End of matrix A
 -2.87  -5.23
  1.63   0.29
 -3.52   4.76
  0.45  -8.41                               :End of matrix B

１行目はタイトル行で読み飛ばされます。
２行目に行列Aの行数(m)、列数(n)、右辺の数(nrhs)を指定しています。
３～６行目に行列Aの要素を指定しています。
７～１０行目に行列Bの要素を指定しています。

出力結果

（本ルーチンの詳細はf08ahf のマニュアルページを参照）

この出力例をダウンロード

 F08AHF Example Program Results

 Minimum-norm solution(s)
             1          2
 1      0.2371     0.7383
 2     -0.4575     0.0158
 3     -0.0085    -0.0161
 4     -0.5192     1.0768
 5      0.0239    -0.6436
 6     -0.0543    -0.6613

５～１０行目に最小ノルム解が出力されています。

ソースコード

（本ルーチンの詳細はf08ahf のマニュアルページを参照）

※本サンプルソースコードは科学技術・統計計算ライブラリである「nAG Fortranライブラリ」のルーチンを呼び出します。
サンプルのコンパイル及び実行方法

このソースコードをダウンロード

    PROGRAM f08ahfe

!      F08AHF Example Program Text

!      Mark 23 Release. nAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : dgelqf, dormlq, dtrsm, nag_wp, x04caf
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       REAL (KIND=nag_wp), PARAMETER   :: one = 1.0E0_nag_wp
       REAL (KIND=nag_wp), PARAMETER   :: zero = 0.0E0_nag_wp
       INTEGER, PARAMETER              :: nin = 5, nout = 6
!      .. Local Scalars ..
       INTEGER                         :: i, ifail, info, lda, ldb, lwork, m,  &
                                          n, nrhs
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE :: a(:,:), b(:,:), tau(:), work(:)
!      .. Executable Statements ..
       WRITE (nout,*) 'F08AHF Example Program Results'
!      Skip heading in data file
       READ (nin,*)
       READ (nin,*) m, n, nrhs
       lda = m
       ldb = n
       lwork = 64*n
       ALLOCATE (a(lda,n),b(ldb,nrhs),tau(n),work(lwork))

!      Read A and B from data file

       READ (nin,*) (a(i,1:n),i=1,m)
       READ (nin,*) (b(i,1:nrhs),i=1,m)

!      Compute the LQ factorization of A
!      The nAG name equivalent of dgelqf is f08ahf
       CALL dgelqf(m,n,a,lda,tau,work,lwork,info)

!      Solve L*Y = B, storing the result in B
!      The nAG name equivalent of dtrsm is f06yjf
       CALL dtrsm('Left','Lower','No transpose','Non-Unit',m,nrhs,one,a,lda,b, &
          ldb)

!      Set rows (M+1) to N of B to zero

       IF (m<n) b(m+1:n,1:nrhs) = zero

!      Compute minimum-norm solution X = (Q**T)*B in B
!      The nAG name equivalent of dormlq is f08akf
       CALL dormlq('Left','Transpose',n,nrhs,m,a,lda,tau,b,ldb,work,lwork, &
          info)

!      Print minimum-norm solution(s)

       WRITE (nout,*)
       FLUSH (nout)

!      ifail: behaviour on error exit
!             =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
       ifail = 0
       CALL x04caf('General',' ',n,nrhs,b,ldb,'Minimum-norm solution(s)', &
          ifail)

    END PROGRAM f08ahfe

Fortranによるサンプルソースコード : 使用ルーチン名：f08ahf

概要

入力データ

出力結果

ソースコード