概要
本サンプルはFortran言語によりLAPACKルーチンZHPEVDを利用するサンプルプログラムです。
エルミート行列のすべての固有値と固有ベクトルを求めます。
ZHPEV例題プログラムは固有値の誤差限界計算方法を示します。
入力データ
（本ルーチンの詳細はZHPEVD のマニュアルページを参照）1 2 3 4 5 6 7 8
| このデータをダウンロード |
ZHPEVD Example Program Data 4 :Value of N 'L' :Value of UPLO (1.0, 0.0) (2.0, 1.0) (2.0, 0.0) (3.0, 1.0) (3.0, 2.0) (3.0, 0.0) (4.0, 1.0) (4.0, 2.0) (4.0, 3.0) (4.0, 0.0) :End of matrix A 'V' :Value of JOB
出力結果
（本ルーチンの詳細はZHPEVD のマニュアルページを参照）1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21
| この出力例をダウンロード |
ZHPEVD Example Program Results
Eigenvalues
1 -4.2443
2 -0.6886
3 1.1412
4 13.7916
Eigenvectors
1 2 3 4
1 -0.3839 0.6470 0.0179 0.3309
-0.2941 0.0000 -0.4453 -0.1986
2 -0.4512 -0.4984 0.5706 0.3728
0.1102 -0.1130 0.0000 -0.2419
3 0.0263 0.2949 -0.1530 0.4870
0.4857 0.3165 0.5273 -0.1938
4 0.5602 -0.2241 -0.2118 0.6155
0.0000 -0.2878 -0.3598 0.0000
ソースコード
（本ルーチンの詳細はZHPEVD のマニュアルページを参照）※本サンプルソースコードのご利用手順は「サンプルのコンパイル及び実行方法」をご参照下さい。
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85
| このソースコードをダウンロード |
Program zhpevd_example
! ZHPEVD Example Program Text
! Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com
! .. Use Statements ..
Use blas_interfaces, Only: dznrm2
Use lapack_example_aux, Only: nagf_file_print_matrix_complex_gen
Use lapack_interfaces, Only: zhpevd
Use lapack_precision, Only: dp
! .. Implicit None Statement ..
Implicit None
! .. Parameters ..
Integer, Parameter :: nin = 5, nout = 6
! .. Local Scalars ..
Complex (Kind=dp) :: scal
Integer :: i, ifail, info, j, k, ldz, liwork, lrwork, lwork, n
Character (1) :: job, uplo
! .. Local Arrays ..
Complex (Kind=dp), Allocatable :: ap(:), work(:), z(:, :)
Real (Kind=dp), Allocatable :: rwork(:), w(:)
Integer, Allocatable :: iwork(:)
! .. Intrinsic Procedures ..
Intrinsic :: abs, conjg, maxloc
! .. Executable Statements ..
Write (nout, *) 'ZHPEVD Example Program Results'
! Skip heading in data file
Read (nin, *)
Read (nin, *) n
ldz = n
liwork = 5*n + 3
lrwork = 2*n*n + 5*n + 1
lwork = 2*n
Allocate (ap(n*(n+1)/2), work(lwork), z(ldz,n), rwork(lrwork), w(n), &
iwork(liwork))
Read (nin, *) uplo
! Read A from data file
If (uplo=='U') Then
Read (nin, *)((ap(i+j*(j-1)/2),j=i,n), i=1, n)
Else If (uplo=='L') Then
Read (nin, *)((ap(i+(2*n-j)*(j-1)/2),j=1,i), i=1, n)
End If
Read (nin, *) job
! Calculate all the eigenvalues and eigenvectors of A
Call zhpevd(job, uplo, n, ap, w, z, ldz, work, lwork, rwork, lrwork, &
iwork, liwork, info)
Write (nout, *)
If (info>0) Then
Write (nout, *) 'Failure to converge.'
Else
! Print eigenvalues and eigenvectors
Write (nout, *) 'Eigenvalues'
Do i = 1, n
Write (nout, 100) i, w(i)
End Do
Write (nout, *)
Flush (nout)
! Normalize the eigenvectors, largest element real
Do i = 1, n
rwork(1:n) = abs(z(1:n,i))
k = maxloc(rwork(1:n), 1)
scal = conjg(z(k,i))/abs(z(k,i))/dznrm2(n, z(1,i), 1)
z(1:n, i) = z(1:n, i)*scal
End Do
! ifail: behaviour on error exit
! =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
ifail = 0
Call nagf_file_print_matrix_complex_gen('General', ' ', n, n, z, ldz, &
'Eigenvectors', ifail)
End If
100 Format (3X, I5, 5X, 2F8.4)
End Program