概要
本サンプルはFortran言語によりLAPACKルーチンZHBEVDを利用するサンプルプログラムです。
エルミート帯行列のすべての固有値と固有ベクトルを求めます。
ZHBEVの例題プログラムは計算された固有値と固有ベクトルの誤差限界の計算方法を示します。
入力データ
（本ルーチンの詳細はZHBEVD のマニュアルページを参照）1 2 3 4 5 6 7 8 9
| このデータをダウンロード |
ZHBEVD Example Program Data
5 2 :Values of N and KD
'L' :Value of UPLO
(1.0, 0.0)
(2.0, 1.0) (2.0, 0.0)
(3.0, 1.0) (3.0, 2.0) (3.0, 0.0)
(4.0, 2.0) (4.0, 3.0) (4.0, 0.0)
(5.0, 3.0) (5.0, 4.0) (5.0, 0.0) :End of matrix A
'V' :Value of JOB
出力結果
（本ルーチンの詳細はZHBEVD のマニュアルページを参照）1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25
| この出力例をダウンロード |
ZHBEVD Example Program Results
Eigenvalues
1 -6.4185
2 -1.4094
3 1.4421
4 4.4856
5 16.9002
Eigenvectors
1 2 3 4 5
1 -0.2534 0.6367 -0.2560 0.0171 0.1051
-0.0538 0.0000 0.3721 0.5500 -0.0983
2 -0.0662 -0.2578 0.5344 -0.2608 0.2516
0.4301 0.2413 0.0000 0.4869 -0.1789
3 0.5274 -0.3039 -0.4245 -0.0399 0.4994
0.0000 -0.3481 0.0915 0.2142 -0.1513
4 0.1061 0.3450 0.4964 -0.0253 0.5611
-0.4981 -0.0832 -0.1546 -0.1700 0.0000
5 -0.4519 -0.2469 -0.1979 0.5614 0.4837
0.0424 0.2634 -0.1114 0.0000 0.2509
ソースコード
（本ルーチンの詳細はZHBEVD のマニュアルページを参照）※本サンプルソースコードのご利用手順は「サンプルのコンパイル及び実行方法」をご参照下さい。
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89
| このソースコードをダウンロード |
Program zhbevd_example
! ZHBEVD Example Program Text
! Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com
! .. Use Statements ..
Use blas_interfaces, Only: dznrm2
Use lapack_example_aux, Only: nagf_file_print_matrix_complex_gen
Use lapack_interfaces, Only: zhbevd
Use lapack_precision, Only: dp
! .. Implicit None Statement ..
Implicit None
! .. Parameters ..
Integer, Parameter :: nin = 5, nout = 6
! .. Local Scalars ..
Complex (Kind=dp) :: scal
Integer :: i, ifail, info, j, k, kd, ldab, ldz, liwork, lrwork, lwork, n
Character (1) :: job, uplo
! .. Local Arrays ..
Complex (Kind=dp), Allocatable :: ab(:, :), work(:), z(:, :)
Real (Kind=dp), Allocatable :: rwork(:), w(:)
Integer, Allocatable :: iwork(:)
! .. Intrinsic Procedures ..
Intrinsic :: abs, conjg, max, maxloc, min
! .. Executable Statements ..
Write (nout, *) 'ZHBEVD Example Program Results'
! Skip heading in data file
Read (nin, *)
Read (nin, *) n, kd
ldab = n
ldz = n
liwork = 5*n + 3
lrwork = 2*n*n + 5*n + 1
lwork = 2*n*n
Allocate (ab(ldab,n), work(lwork), z(ldz,n), rwork(lrwork), w(n), &
iwork(liwork))
! Read A from data file
Read (nin, *) uplo
If (uplo=='U') Then
Do i = 1, n
Read (nin, *)(ab(kd+1+i-j,j), j=i, min(n,i+kd))
End Do
Else If (uplo=='L') Then
Do i = 1, n
Read (nin, *)(ab(1+i-j,j), j=max(1,i-kd), i)
End Do
End If
Read (nin, *) job
! Calculate all the eigenvalues and eigenvectors of A
Call zhbevd(job, uplo, n, kd, ab, ldab, w, z, ldz, work, lwork, rwork, &
lrwork, iwork, liwork, info)
Write (nout, *)
If (info>0) Then
Write (nout, *) 'Failure to converge.'
Else
! Print eigenvalues and eigenvectors
Write (nout, *) 'Eigenvalues'
Do i = 1, n
Write (nout, 100) i, w(i)
End Do
Write (nout, *)
Flush (nout)
! Normalize the eigenvectors, largest element real
Do i = 1, n
rwork(1:n) = abs(z(1:n,i))
k = maxloc(rwork(1:n), 1)
scal = conjg(z(k,i))/abs(z(k,i))/dznrm2(n, z(1,i), 1)
z(1:n, i) = z(1:n, i)*scal
End Do
! ifail: behaviour on error exit
! =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
ifail = 0
Call nagf_file_print_matrix_complex_gen('General', ' ', n, n, z, ldz, &
'Eigenvectors', ifail)
End If
100 Format (3X, I5, 5X, 2F8.4)
End Program