複素線形方程式: 一般行列 : (右辺はベクトル)

LAPACKサンプルソースコード : 使用ルーチン名：ZGESV

ホーム > LAPACKサンプルプログラム目次 > 複素線形方程式 > 一般行列

概要

本サンプルはFortran言語によりLAPACKルーチンZGESVを利用するサンプルプログラムです。

:6x4の行列の特異値と左および右特異ベクトルを求めます。

\begin{displaymath} A = \left( \begin{array}{rrrrrr} 0.96 - 0.81i & -0.03 + 0... ...0 - 0.12i & -0.07 + 1.23i & 0.26 + 0.26i \end{array} \right), \end{displaymath}

計算された特異値と特異ベクトルの誤差限界近似値も合わせて求めます。

ZGESDDの例題プログラムは $ m \le n$の場合の特異値分解を示します。

入力データ

（本ルーチンの詳細はZGESV のマニュアルページを参照）
このデータをダウンロード 
ZGESV Example Program Data

   4                                                      :Value of N

 (-1.34, 2.55) ( 0.28, 3.17) (-6.39,-2.20) ( 0.72,-0.92)
 (-0.17,-1.41) ( 3.31,-0.15) (-0.15, 1.34) ( 1.29, 1.38)
 (-3.29,-2.39) (-1.91, 4.42) (-0.14,-1.35) ( 1.72, 1.35)
 ( 2.41, 0.39) (-0.56, 1.47) (-0.83,-0.69) (-1.96, 0.67)  :End of matrix A

 (26.26,51.78) ( 6.43,-8.68) (-5.75,25.31) ( 1.16, 2.57)  :End of vector b

出力結果

（本ルーチンの詳細はZGESV のマニュアルページを参照）
この出力例をダウンロード 
 ZGESV Example Program Results

 Solution
    ( 1.0000, 1.0000) ( 2.0000,-3.0000) (-4.0000,-5.0000) ( 0.0000, 6.0000)

 Details of factorization
                    1                 2                 3                 4
 1  (-3.2900,-2.3900) (-1.9100, 4.4200) (-0.1400,-1.3500) ( 1.7200, 1.3500)
 2  ( 0.2376, 0.2560) ( 4.8952,-0.7114) (-0.4623, 1.6966) ( 1.2269, 0.6190)
 3  (-0.1020,-0.7010) (-0.6691, 0.3689) (-5.1414,-1.1300) ( 0.9983, 0.3850)
 4  (-0.5359, 0.2707) (-0.2040, 0.8601) ( 0.0082, 0.1211) ( 0.1482,-0.1252)

 Pivot indices
           3          2          3          4

ソースコード

（本ルーチンの詳細はZGESV のマニュアルページを参照）

※本サンプルソースコードのご利用手順は「サンプルのコンパイル及び実行方法」をご参照下さい。
このソースコードをダウンロード 
    Program zgesv_example

!     ZGESV Example Program Text

!     Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com

!     .. Use Statements ..
      Use lapack_example_aux, Only: nagf_file_print_matrix_complex_gen_comp
      Use lapack_interfaces, Only: zgesv
      Use lapack_precision, Only: dp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter :: nin = 5, nout = 6
!     .. Local Scalars ..
      Integer :: i, ifail, info, lda, ldb, n
!     .. Local Arrays ..
      Complex (Kind=dp), Allocatable :: a(:, :), b(:)
      Integer, Allocatable :: ipiv(:)
      Character (1) :: clabs(1), rlabs(1)
!     .. Executable Statements ..
      Write (nout, *) 'ZGESV Example Program Results'
      Write (nout, *)
!     Skip heading in data file
      Read (nin, *)
      Read (nin, *) n
      lda = n
      ldb = n
      Allocate (a(lda,n), b(ldb), ipiv(n))

!     Read A and B from data file

      Read (nin, *)(a(i,1:n), i=1, n)
      Read (nin, *) b(1:n)

!     Solve the equations Ax = b for x

      Call zgesv(n, 1, a, lda, ipiv, b, ldb, info)

      If (info==0) Then

!       Print solution

        Write (nout, *) 'Solution'
        Write (nout, 100) b(1:n)

!       Print details of factorization

        Write (nout, *)
        Flush (nout)

!       ifail: behaviour on error exit
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
        Call nagf_file_print_matrix_complex_gen_comp('General', ' ', n, n, a, &
          lda, 'Bracketed', 'F7.4', 'Details of factorization', 'Integer', &
          rlabs, 'Integer', clabs, 80, 0, ifail)

!       Print pivot indices

        Write (nout, *)
        Write (nout, *) 'Pivot indices'
        Write (nout, 110) ipiv(1:n)
      Else
        Write (nout, 120) 'The (', info, ',', info, ')', &
          ' element of the factor U is zero'
      End If

100   Format ((3X,4(' (',F7.4,',',F7.4,')',:)))
110   Format (1X, 7I11)
120   Format (1X, A, I3, A, I3, A, A)
    End Program


ご案内
関連情報
Privacy Policy  /  Trademarks