概要
本サンプルはFortran言語によりLAPACKルーチンDSPSVを利用するサンプルプログラムです。
以下の式を解きます。
は対称行列です。
の分解についての詳細 も合わせて出力されます。
入力データ
（本ルーチンの詳細はDSPSV のマニュアルページを参照）1 2 3 4 5 6 7
| このデータをダウンロード |
DSPSV Example Program Data
4 :Value of N
-1.81 2.06 0.63 -1.15
1.15 1.87 4.20
-0.21 3.87
2.07 :End of matrix A
0.96 6.07 8.38 9.50 :End of vector b
出力結果
（本ルーチンの詳細はDSPSV のマニュアルページを参照）1 2 3 4 5 6 7 8 9 10 11 12 13 14
| この出力例をダウンロード |
DSPSV Example Program Results
Solution
-5.0000 -2.0000 1.0000 4.0000
Details of the factorization
1 2 3 4
1 0.4074 0.3031 -0.5960 0.6537
2 -2.5907 0.8115 0.2230
3 1.1500 4.2000
4 2.0700
Pivot indices
1 2 -2 -2
ソースコード
（本ルーチンの詳細はDSPSV のマニュアルページを参照）※本サンプルソースコードのご利用手順は「サンプルのコンパイル及び実行方法」をご参照下さい。
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77
| このソースコードをダウンロード |
Program dspsv_example
! DSPSV Example Program Text
! Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com
! .. Use Statements ..
Use lapack_example_aux, Only: nagf_file_print_matrix_real_packed
Use lapack_interfaces, Only: dspsv
Use lapack_precision, Only: dp
! .. Implicit None Statement ..
Implicit None
! .. Parameters ..
Integer, Parameter :: nin = 5, nout = 6
Character (1), Parameter :: uplo = 'U'
! .. Local Scalars ..
Integer :: i, ifail, info, j, n
! .. Local Arrays ..
Real (Kind=dp), Allocatable :: ap(:), b(:)
Integer, Allocatable :: ipiv(:)
! .. Executable Statements ..
Write (nout, *) 'DSPSV Example Program Results'
Write (nout, *)
! Skip heading in data file
Read (nin, *)
Read (nin, *) n
Allocate (ap((n*(n+1))/2), b(n), ipiv(n))
! Read the upper or lower triangular part of the matrix A from
! data file
If (uplo=='U') Then
Read (nin, *)((ap(i+(j*(j-1))/2),j=i,n), i=1, n)
Else If (uplo=='L') Then
Read (nin, *)((ap(i+((2*n-j)*(j-1))/2),j=1,i), i=1, n)
End If
! Read b from data file
Read (nin, *) b(1:n)
! Solve the equations Ax = b for x
Call dspsv(uplo, n, 1, ap, ipiv, b, n, info)
If (info==0) Then
! Print solution
Write (nout, *) 'Solution'
Write (nout, 100) b(1:n)
! Print details of factorization
Write (nout, *)
Flush (nout)
! ifail: behaviour on error exit
! =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
ifail = 0
Call nagf_file_print_matrix_real_packed(uplo, 'Non-unit diagonal', n, &
ap, 'Details of the factorization', ifail)
! Print pivot indices
Write (nout, *)
Write (nout, *) 'Pivot indices'
Write (nout, 110) ipiv(1:n)
Else
Write (nout, 120) 'The diagonal block ', info, ' of D is zero'
End If
100 Format ((3X,7F11.4))
110 Format (1X, 7I11)
120 Format (1X, A, I3, A)
End Program