概要
本サンプルはFortran言語によりLAPACKルーチンDPPSVを利用するサンプルプログラムです。
以下の式を解きます。
は対称正定値行列です。
のコレスキー分解についての詳細 も合わせて出力されます。
入力データ
（本ルーチンの詳細はDPPSV のマニュアルページを参照）1 2 3 4 5 6 7
| このデータをダウンロード |
DPPSV Example Program Data
4 :Value of N
4.16 -3.12 0.56 -0.10
5.03 -0.83 1.18
0.76 0.34
1.18 :End of matrix A
8.70 -13.35 1.89 -4.14 :End of vector b
出力結果
（本ルーチンの詳細はDPPSV のマニュアルページを参照）1 2 3 4 5 6 7 8 9 10 11
| この出力例をダウンロード |
DPPSV Example Program Results
Solution
1.0000 -1.0000 2.0000 -3.0000
Cholesky factor
1 2 3 4
1 2.0396 -1.5297 0.2746 -0.0490
2 1.6401 -0.2500 0.6737
3 0.7887 0.6617
4 0.5347
ソースコード
（本ルーチンの詳細はDPPSV のマニュアルページを参照）※本サンプルソースコードのご利用手順は「サンプルのコンパイル及び実行方法」をご参照下さい。
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70
| このソースコードをダウンロード |
Program dppsv_example
! DPPSV Example Program Text
! Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com
! .. Use Statements ..
Use lapack_example_aux, Only: nagf_file_print_matrix_real_packed
Use lapack_interfaces, Only: dppsv
Use lapack_precision, Only: dp
! .. Implicit None Statement ..
Implicit None
! .. Parameters ..
Integer, Parameter :: nin = 5, nout = 6
Character (1), Parameter :: uplo = 'U'
! .. Local Scalars ..
Integer :: i, ifail, info, j, n
! .. Local Arrays ..
Real (Kind=dp), Allocatable :: ap(:), b(:)
! .. Executable Statements ..
Write (nout, *) 'DPPSV Example Program Results'
Write (nout, *)
! Skip heading in data file
Read (nin, *)
Read (nin, *) n
Allocate (ap((n*(n+1))/2), b(n))
! Read the upper or lower triangular part of the matrix A from
! data file
If (uplo=='U') Then
Read (nin, *)((ap(i+(j*(j-1))/2),j=i,n), i=1, n)
Else If (uplo=='L') Then
Read (nin, *)((ap(i+((2*n-j)*(j-1))/2),j=1,i), i=1, n)
End If
! Read b from data file
Read (nin, *) b(1:n)
! Solve the equations Ax = b for x
Call dppsv(uplo, n, 1, ap, b, n, info)
If (info==0) Then
! Print solution
Write (nout, *) 'Solution'
Write (nout, 100) b(1:n)
! Print details of factorization
Write (nout, *)
Flush (nout)
! ifail: behaviour on error exit
! =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
ifail = 0
Call nagf_file_print_matrix_real_packed(uplo, 'Non-unit diagonal', n, &
ap, 'Cholesky factor', ifail)
Else
Write (nout, 110) 'The leading minor of order ', info, &
' is not positive definite'
End If
100 Format ((3X,7F11.4))
110 Format (1X, A, I3, A)
End Program