関連情報

F分布から疑似乱数ベクトルを生成

Fortranによるサンプルソースコード
使用ルーチン名:g05shf

Keyword: F分布, 疑似乱数ベクトル

概要

本サンプルはF分布から疑似乱数ベクトルの生成を行うFortranによるサンプルプログラムです。 本サンプルは以下に示される確率密度関数をもつ、2つの自由度と3つの自由度をもつF分布から5個の疑似乱数を生成し出力します。

F分布のデータ 

※本サンプルはNAG Fortranライブラリに含まれるルーチン g05shf() のExampleコードです。本サンプル及びルーチンの詳細情報は g05shf のマニュアルページをご参照ください。
ご相談やお問い合わせはこちらまで

入力データ

(本ルーチンの詳細はg05shf のマニュアルページを参照)

このデータをダウンロード
G05SHF Example Program Data
1  1  1762543     :: GENID,SUBID,SEED(1)
5 3               :: N,NMIX
2 3               :: DF1,DF2

  • 1行目はタイトル行で読み飛ばされます。
  • 2行目に使用する生成器(genid=1:NAG基本生成器)、生成器に関する情報(subid=1:GENIDが1の場合この値は参照されません)、生成器の初期値(seed=1762543)を指定しています。
  • 3行目に生成される疑似乱数の数(n=5)を指定しています。
  • 4行目に分布の自由度の数(df1,df2)を指定しています。

出力結果

(本ルーチンの詳細はg05shf のマニュアルページを参照)

この出力例をダウンロード
 G05SHF Example Program Results

     1.4401
     1.8083
     0.3638
     0.5464
     4.0895

  • 3〜7行目に生成された疑似乱数が出力されています。

ソースコード

(本ルーチンの詳細はg05shf のマニュアルページを参照)

※本サンプルソースコードは科学技術・統計計算ライブラリである「NAG Fortranライブラリ」のルーチンを呼び出します。
サンプルのコンパイル及び実行方法


このソースコードをダウンロード
    PROGRAM g05shfe

!      G05SHF Example Program Text

!      Mark 23 Release. NAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : g05kff, g05shf, nag_wp
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: lseed = 1, nin = 5, nout = 6
!      .. Local Scalars ..
       INTEGER                         :: df1, df2, genid, ifail, lstate, n,   &
                                          subid
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE :: x(:)
       INTEGER                         :: seed(lseed)
       INTEGER, ALLOCATABLE            :: state(:)
!      .. Executable Statements ..
       WRITE (nout,*) 'G05SHF Example Program Results'
       WRITE (nout,*)

!      Skip heading in data file
       READ (nin,*)

!      Read in the base generator information and seed
       READ (nin,*) genid, subid, seed(1)

!      Initial call to initialiser to get size of STATE array
       lstate = 0
       ALLOCATE (state(lstate))
       ifail = 0
       CALL g05kff(genid,subid,seed,lseed,state,lstate,ifail)

!      Reallocate STATE
       DEALLOCATE (state)
       ALLOCATE (state(lstate))

!      Initialize the generator to a repeatable sequence
       ifail = 0
       CALL g05kff(genid,subid,seed,lseed,state,lstate,ifail)

!      Read in sample size
       READ (nin,*) n

       ALLOCATE (x(n))

!      Read in the distribution parameters
       READ (nin,*) df1, df2

!      Generate the variates
       ifail = 0
       CALL g05shf(n,df1,df2,state,x,ifail)

!      Display the variates
       WRITE (nout,99999) x(1:n)

99999  FORMAT (1X,F10.4)
    END PROGRAM g05shfe


Results matter. Trust NAG.

Privacy Policy | Trademarks