関連情報
ホーム > 製品 > NAG数値計算ライブラリ > NAG Fortranライブラリ > サンプルソースコード集 > 正規誤差をもつ一般化線形モデルのフィット

正規誤差をもつ一般化線形モデルのフィット

Fortranによるサンプルソースコード
使用ルーチン名:g02gaf

Keyword: 正規誤差, 一般化線形モデル, フィット

概要

本サンプルは正規誤差をもつ一般化線形モデルのフィットを行うFortranによるサンプルプログラムです。 本サンプルは以下に示されるデータについて一般化線形モデルのフィットを行います。

一般化線形モデルのフィットのデータ 

※本サンプルはNAG Fortranライブラリに含まれるルーチン g02gaf() のExampleコードです。本サンプル及びルーチンの詳細情報は g02gaf のマニュアルページをご参照ください。
ご相談やお問い合わせはこちらまで

入力データ

(本ルーチンの詳細はg02gaf のマニュアルページを参照)

このデータをダウンロード
G02GAF Example Program Data
'R' 'M' 'N' 'U' 5 1  0.0 :: LINK,MEAN,OFFSET,WEIGHT,N,M,S
1.0 25.0
2.0 10.0
3.0  6.0
4.0  4.0
5.0  3.0                 :: End of X,Y
 1                       :: ISX
0  1.0E-6  5.0E-5  10    :: IPRINT,EPS,TOL,MAXIT 

  • 1行目はタイトル行で読み飛ばされます。
  • 2行目はどのリンク関数が使用されるか(link='R':相互リンク(reciprocal link))、一般化線形モデルの引数に切片が含まれるかどうか(mean='M':切片を含める)、オフセットが必要かどうか(offset='N':不要)、重みづけをするかどうか(weight='U':重みづけをしない)、観測値の数(n=5)、独立変数の数(m=1)、モデルのスケール引数(s=0.0:スケール引数が残差平均平方から推定される)を指定しています。
  • 3〜7行目に独立変数の観測値(x)と従属変数の観測値(y)を指定しています。
  • 8行目はモデルに独立変数が含まれるかどうか(isx)を指定しています。"1"は含まれることを意味します。
  • 9行目は反復の情報の出力が必要かどうか(iprint=0:不要)、独立変数がフルランクかどうかそうでない場合ランクは何か(eps=1.0E-6)、モデルのフィットに必要な正確さ(tol=5.0E-5)、最大反復数(maxit=10)を指定しています。

出力結果

(本ルーチンの詳細はg02gaf のマニュアルページを参照)

この出力例をダウンロード
 G02GAF Example Program Results

 Residual sum of squares     =   0.3872E+00
  Residual degrees of freedom =  3

       Estimate    Standard error

        -0.0239        0.0028
         0.0638        0.0026

      Y        FV     Residual       H

    25.0     25.04     -0.0387     0.995
    10.0      9.64      0.3613     0.458
     6.0      5.97      0.0320     0.268
     4.0      4.32     -0.3221     0.167
     3.0      3.39     -0.3878     0.112

  • 3行目に残差平方和が出力されています。
  • 4行目に自由度が出力されています。
  • 6〜9行目に一般化線形モデルの引数の推定値と標準誤差が出力されています。
  • 11〜17行目に従属変数の観測値、フィットされた値、残差、てこ値が出力されています。

ソースコード

(本ルーチンの詳細はg02gaf のマニュアルページを参照)

※本サンプルソースコードは科学技術・統計計算ライブラリである「NAG Fortranライブラリ」のルーチンを呼び出します。
サンプルのコンパイル及び実行方法


このソースコードをダウンロード
    PROGRAM g02gafe

!      G02GAF Example Program Text

!      Mark 23 Release. NAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : g02gaf, nag_wp
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: nin = 5, nout = 6
!      .. Local Scalars ..
       REAL (KIND=nag_wp)              :: a, eps, rss, s, tol
       INTEGER                         :: i, idf, ifail, ip, iprint, irank,    &
                                          ldv, ldx, lwt, m, maxit, n
       CHARACTER (1)                   :: link, mean, offset, weight
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE :: b(:), cov(:), se(:), v(:,:), wk(:),  &
                                          wt(:), x(:,:), y(:)
       INTEGER, ALLOCATABLE            :: isx(:)
!      .. Intrinsic Functions ..
       INTRINSIC                          count
!      .. Executable Statements ..
       WRITE (nout,*) 'G02GAF Example Program Results'
       WRITE (nout,*)

!      Skip heading in data file
       READ (nin,*)

!      Read in the problem size
       READ (nin,*) link, mean, offset, weight, n, m, s

       IF (weight=='W' .OR. weight=='w') THEN
          lwt = n
       ELSE
          lwt = 0
       END IF
       ldx = n
       ALLOCATE (x(ldx,m),isx(m),y(n),wt(lwt))

!      Read in the data
       IF (lwt>0) THEN
          READ (nin,*) (x(i,1:m),y(i),wt(i),i=1,n)
       ELSE
          READ (nin,*) (x(i,1:m),y(i),i=1,n)
       END IF

!      Read in variable inclusion flags
       READ (nin,*) isx(1:m)

!      Calculate IP
       ip = count(isx(1:m)>0)
       IF (mean=='M' .OR. mean=='m') THEN
          ip = ip + 1
       END IF

!      Read in power for exponential link
       IF (link=='E' .OR. link=='e') THEN
          READ (nin,*) a
       END IF

       ldv = n
       ALLOCATE (b(ip),se(ip),cov(ip*(ip+1)/2),v(ldv,ip+7),wk((ip*ip+3*ip+ &
          22)/2))

!      Read in the offset
       IF (offset=='Y' .OR. offset=='y') THEN
          READ (nin,*) v(1:n,7)
       END IF

!      Read in control parameters
       READ (nin,*) iprint, eps, tol, maxit

!      Fit the generalized linear model with Normal errors
       ifail = -1
       CALL g02gaf(link,mean,offset,weight,n,x,ldx,m,isx,ip,y,wt,s,a,rss,idf, &
          b,irank,se,cov,v,ldv,tol,maxit,iprint,eps,wk,ifail)
       IF (ifail/=0) THEN
          IF (ifail<6) THEN
             GO TO 20
          END IF
       END IF

!      Display results
       WRITE (nout,99999) 'Residual sum of squares     = ', rss
       WRITE (nout,99998) ' Residual degrees of freedom = ', idf
       WRITE (nout,*)
       WRITE (nout,*) '      Estimate    Standard error'
       WRITE (nout,*)
       WRITE (nout,99997) (b(i),se(i),i=1,ip)
       WRITE (nout,*)
       WRITE (nout,*) '     Y        FV     Residual       H'
       WRITE (nout,*)
       WRITE (nout,99996) (y(i),v(i,2),v(i,5),v(i,6),i=1,n)

20     CONTINUE

99999  FORMAT (1X,A,E12.4)
99998  FORMAT (1X,A,I2)
99997  FORMAT (1X,2F14.4)
99996  FORMAT (1X,F7.1,F10.2,F12.4,F10.3)
    END PROGRAM g02gafe


Results matter. Trust NAG.

Privacy Policy | Trademarks